Ayo Membuat Program Pascal/Algoritma Pencarian

Pada halaman ini, akan dipelajari mengenai konsep algoritma/logika dari pencarian data (search), meliputi:

Pencarian Linier/Sekuensial sunting

Pencarian Linier atau Pencarian Sekuensial (Bah.Ingg: Linear Search atau Sequential Search) adalah pencarian data secara linier (garis lurus), artinya adalah pencarian dilakukan secara teratur (secara sekuensial) dari awal sampai akhir data (atau bisa juga dari akhir ke awal data). Berikut adalah 2 fakta penting tentang pencarian linier:

  • Hanya bagus untuk dipakai pada data yang acak/tak terurut (unsorted)
  • Kompleksitasnya adalah O(n)

Berikut adalah implementasi dari pencarian linier memakai function untuk pencarian data bertipe string:

type
   TArrString = array of string;

function CariLinier(var Arr: TArrString; Cari: string): LongInt;
var
   Idx, Batas, Ketemu: LongInt;

begin
   Idx:= Low(Arr); 
   Batas:= High(Arr); 
   Ketemu:= -1;
   while (Idx <= Batas) and (Ketemu = -1) do begin
      if Arr[Idx] = Cari then Ketemu:= Idx; 
      Inc(Idx);
   end;
   CariLinier:= Ketemu;
end;

Penjelasannya:

type
   TArrString = array of string;

function CariLinier(var Arr: TArrString; Cari: string): LongInt;
var
   Idx, Batas, Ketemu: LongInt;

begin
   Idx:= Low(Arr);     // Dapatkan index terendah dari array
   Batas:= High(Arr);  // Dapatkan index tertinggi dari array
   Ketemu:= -1;        // Asumsi awal: belum ketemu

   // Lakukan perulangan selama data yang dicek belum habis
   // (Idx <= Batas) dan belum ketemu (Ketemu = -1)
   while (Idx <= Batas) and (Ketemu = -1) do begin

      // Jika array di posisi Idx adalah data yang dicari, maka
      // posisi Ketemu ada di posisi Idx saat ini
      if Arr[Idx] = Cari then Ketemu:= Idx;

      // Naikkan posisi Idx (Cek data berikutnya) 
      Inc(Idx);
   end;
   CariLinier:= Ketemu;
end;

Pencarian Biner sunting

Pencarian Biner (Bah.Ingg: Binary Search) adalah pencarian data secara eliminasi biner berulang/terus-menerus. Maksudnya adalah pada saat pencarian data, 1 kelompok data yang sudah urut dibagi menjadi 2 subkelompok. Lalu salah satu subkelompok dieliminasi, sehingga ruang lingkup pencarian data menjadi lebih sedikit. Kemudian subkelompok yang tersisa dibagi lagi menjadi 2 subkelompok lagi, demikian dilakukan secara berulang-ulang.

Sebagai contoh, misalnya diinginkan mencari data nama Irawan di sekumpulan data nama yang sudah terurut. Apabila kelompok data ini dibagi 2, ternyata di bagian tengah terdapat nama Leny. Maka subkelompok data sesudah Leny akan dieliminasi, karena tidak mungkin nama Irawan akan terdapat pada data huruf L s/d Z. Sedangkan, subkelompok sebelum Leny, kemudian akan dibagi 2 lagi, dan diperiksa ulang. Ternyata kali ini di bagian tengah terdapat nama Gery. Maka kelompok data sebelum Gery akan dieliminasi, karena tidak mungkin terdapat data Irawan pada huruf A s/d G. Demikian seterusnya terjadi, proses eliminasi ruang lingkup pencarian data menjadi semakin sedikit secara berulang.

Berikut adalah 3 fakta penting mengenai pencarian biner:

  • Hanya bisa berfungsi pada data yang sudah terurut (sorted), ini adalah syarat mutlak dari pencarian biner
  • Merupakan salah satu contoh penerapan cara kerja dari konsep Divide and Conquer
  • Kompleksitasnya adalah O(lg n)

Ini adalah implementasi dari pencarian biner memakai function untuk pencarian data bertipe string:

type
   TArrString = array of string;

function CariBiner(var Arr: TArrString; Cari: string): LongInt;
var
   Awal, Akhir, Tengah, Ketemu: LongInt;

begin
   Awal:= Low(Arr);
   Akhir:= High(Arr);
   Ketemu:= -1;
   while (Awal <= Akhir) and (Ketemu = -1) do begin
      Tengah:= (Awal + Akhir) shr 1;
      if Arr[Tengah] = Cari then Ketemu:= Tengah else begin
         if Cari < Arr[Tengah] then Akhir:= Tengah-1 else Awal:= Tengah+1;
      end;
   end;
   CariBiner:= Ketemu;
end;

Penjelasannya:

type
   TArrString = array of string;

function CariBiner(var Arr: TArrString; Cari: string): LongInt;
var
   Awal, Akhir, Tengah, Ketemu: LongInt;

begin
   Awal:= Low(Arr);   // Posisi awal pencarian
   Akhir:= High(Arr); // Posisi akhir pencarian
   Ketemu:= -1;       // Asumsi awal: belum ketemu

   // Ulangi selama ruang lingkup pencarian masih ada (Awal <= Akhir)
   // dan data yang dicari belum ketemu (Ketemu = -1)
   while (Awal <= Akhir) and (Ketemu = -1) do begin

      // Hitung lokasi data yang di tengah ruang lingkup pencarian
      Tengah:= (Awal + Akhir) shr 1;

      { Cek apakah data yang di tengah merupakan data yang dicari,
        apabila bukan, pindahkan ruang lingkup pencarian,
        kalau data ada di sebelah kiri (lebih kecil <),
        maka batas akhir yang dikurangi (Akhir:= Tengah - 1),
        sedangkan jika data ada di sebelah kanan,
        maka batas awal yang ditambah (Awal:= Tengah + 1) }
      if Arr[Tengah] = Cari then Ketemu:= Tengah else begin
         if Cari < Arr[Tengah] then Akhir:= Tengah-1 else Awal:= Tengah+1;
      end;
   end;
   CariBiner:= Ketemu;
end;